在Common Lisp中，一个变量可以保存任何类型的值，并且这些值带有用于运行期类型检查的类型信息²。Common Lisp是动态类型的——类型错误会被动态地检测到。另一方面，Common Lisp是一种 强类型 （ strongly typed ）语言，所有的类型错误都将被检测到——无法将一个对象作为其不属于的一种类型的实例来对待。³

Lisp中所有符号只有两种状态：绑定和未绑定。⁴我们定义一个变量的同时，也建立了一个绑定，例如：

CL-USER> (setf S 10)
10
CL-USER> S
10

上述过程图形化表示即是：

表达式 (setf S 10) 执行了下面两个步骤：

1. 把符号 S 跟内存中的一存储单元建立起绑定。之后，符号 S 出现的地方就代表（引用）了这一存储单元。
2. 把符号 S 所引用的存储单元的值设为整数10。我们接着在命令行中敲入 S 求值时，REPL会依据之前建立起的绑定找到那个存储单元并把值打印出来。

Common Lisp中所有的值，至少从概念上讲，都是对对象的引用（references）。⁵将一个变量赋予新值只会改变此变量将引用哪个对象，对其之前引用的对象没有影响。但是，如果一个变量保存了对一个可变对象的引用，你可以用这个引用来修改此对象，而且这种改动将作用于其他引用这个相同对象的代码。⁶

默认情况下Common Lisp中所有的绑定形式引入的都是词法作用域变量。词法作用域变量只能被文本上位于绑定形式之内的代码所引用。

Common Lisp中将词法作用域和嵌套函数结合在一起时，按照词法作用域的规则，只有文本上位于绑定形式之内的代码可以引用词法变量，但是如果一个匿名函数包含了一个对于封闭区域内的词法变量的引用，例如下面的表达式：

(let ((count 0))
  #'(lambda ()
      (setf count (1+ count))))

依据词法作用域的规则， lambda 形式中对于 count 的引用是合法的。当这个含有引用的匿名函数作为 LET 形式的值被返回，通过 FUNCALL ，被不在 LET 作用域之内的代码所调用，这样会发生什么？正如你将看到的那样，如果 count 是一个词法变量，代码正常工作，控制流进入 LET 形式时所创建的 count 绑定根据需要将被尽可能长时间得保持下来，只要某处保留了一个对 LET 形式返回的函数对象的引用。这个匿名函数被称为一个 闭包 ，因为它封装了由 LET 创建的绑定。¹³

理解闭包的关键在于，被捕捉的是 绑定 而不是变量名所引用的对象的值。因此，一个闭包不仅能访问其封装的变量的值，还可以在闭包被不断调用时赋予其新值。例如，你可以将前面表达式所创建的闭包赋给一个全局变量：

(defparameter *fn* (let ((count 0))
                     #'(lambda ()
                         (setf count (1+ count)))))

然后，每一次你调用它时， count 的值将被加1：

CL-USER> (funcall *fn*)
1
CL-USER> (funcall *fn*)
2
CL-USER> (funcall *fn*)
3

单独一个闭包可以简单地通过引用来封装多个变量绑定。多个闭包也可以捕捉一个相同的绑定。例如，下面的表达式返回了一个由三个闭包组成的列表，一个闭包用来递增其所闭合的 count 绑定的值，另一个递减它，还有一个返回 count 绑定的当前的值：

(let ((count 0))
  (list
   #'(lambda () (incf count))
   #'(lambda () (decf count))
   #'(lambda () count)))

词法绑定通过限制变量的作用域使代码易于理解。但是，有时候仍然需要一个全局变量——一个从程序的任何位置都可以引用到的变量。随意使用全局变量将使代码变得杂乱无章，就像毫无节制地使用 goto 那样，但全局变量有其合理的用途并以某种形式存在于几乎每一种程序语言当中。正如你即将看到的，Lisp的全局变量和动态变量，都更加有用并且更易于管理。

Common Lisp提供两种方式来创建全局变量： DEFVAR 和 DEFPARAMETER 。两种方式都接受一个变量名，一个初始值和一个可选的文档字符串。在被 DEFVAR 和 DEFPARAMETER 定义之后，该变量名将可以在任何地方使用来引用全局变量的当前绑定。全局变量习惯上被命名为以 * 开始和结束，遵守该命名约定非常重要。 DEFVAR 和 DEFPARAMETER 的示例如下：

(defvar *count* 0
  "Count of widgets made so far.")

(defparameter *gap-tolerance* 0.001
  "Tolerance to be allowed in widget gaps.")

这两种形式的区别在于 DEFPARAMETER 总是将初始值赋予定义的变量，而 DEFVAR 只会在变量未定义时才这样做。 DEFVAR 形式也可以不带初始值来使用，用于定义一个没有初始值的全局变量。这样的变量称为未绑定的（ unbound ）。

从实践上讲，应该使用 DEFVAR 来定义那些包含你想持久使用的数据的变量，即是你已经改动了使用此变量的代码。例如，假设前面定义的两个变量是一个用来控制工厂组件生产程序的一部分，使用 DEFVAR 来定义 *count* 变量就比较合适，因为到目前为止生产的组件的数量不会因为你改动了组件生产的代码就变得无效。¹⁴

另一方面，假设变量 *gap-tolerance* 对生产组件的代码的行为有影响。假如你觉着你需要一个或紧或松的容差值，然后改动了 DEFPARAMETER 形式中的值，那么就要在重新编译或者加载文件时使这一改变产生效果。

使用 DEFVAR 和 DEFPARAMETER 定义了一个变量之后，你就可以在任何地方来引用它。例如，可以定义下面的函数来递增已经生产的组件的数量：

(defun increment-widget-count ()
  (incf *count*))

全局变量的优势在于不用到处传递它们。

所有的全局变量都是动态变量。

从概念上说，为一个动态变量创建的新绑定会被压入一个为此变量设置的绑定栈中，对该变量的引用总是使用最新的绑定，当一个绑定形式返回时，它所创建的绑定会被从栈上弹出，从而暴露出前一个绑定。¹⁵

一个简单的揭示其如何工作的例子：

(defvar *x* 10)

(defun foo ()
  (format t "X: ~d~%" *x*))

上面这个 DEFVAR 为变量 *x* 创建了一个到数值10的绑定，函数 foo 中对 *x* 的引用将动态地查找其当前绑定，如果你从顶层调用 foo ，由 DEFVAR 创建的全局绑定就是唯一可用的绑定，所以它将打印出10：

CL-USER> (foo)
X: 10
NIL

但是你可以用 LET 创建临时的绑定来覆盖全局的绑定，这样 foo 将打印一个不同的值：

CL-USER> (let ((*x* 20)) (foo))
X: 20
NIL

现在不使用 LET 再调用 foo ，它将再次看到全局绑定：

CL-USER> (foo)
X: 10
NIL

现在定义另一个函数：

(defun bar ()
  (foo)
  (let ((*x* 20)) (foo))
  (foo))

注意中间的那个对函数 foo 的调用被包含在一个将 *x* 绑定到新值20的 LET 中，运行 bar 得到的结果如下：

CL-USER> (bar)
X: 10
X: 20
X: 10
NIL

可一看到，第一次对 foo 的调用看到的是全局绑定，其值为10。但中间的那个调用看到的却是新的绑定，其值为20。在 LET 之后， foo 再次看到了全局绑定。

和词法绑定一样，赋予新值仅仅影响当前绑定。为了理解这点，可以重定义包含一个对 *x* 赋值的 foo ：

(defun foo ()
  (format t "Before assignment~18tX: ~d~%" *x*)
  (setf *x* (+ 1 *x*))
  (format t "After assignment~18tX: ~d~%" *x*))

现在 foo 打印 *x* 的值，对其递增，然后再次打印它。如果只运行 foo ，将看到这样的结果：

CL-USER> (foo)
Before assignment X: 10
After assignment  X: 11
NIL

看起来挺正常，现在运行 bar ：

CL-USER> (bar)
Before assignment X: 11
After assignment  X: 12
Before assignment X: 20
After assignment  X: 21
Before assignment X: 12
After assignment  X: 13
NIL

注意 *x* 从11开始——之前的 foo 调用改变了全局的值。 bar 里面第一次调用 foo 将这个全局绑定的值递增到了12。中间的调用因为 LET 没有看到全局绑定。最后一个对 foo 的调用再次看到了全局绑定，并将其从12递增到了13。

那么它是怎样工作的？ LET 是如何知道在它绑定 *x* 时打算创建的是动态绑定而不是词法绑定？这是因为该名称已经被声明为特殊的（special）了。¹⁶每一个由 DEFVAR 和 DEFPARAMETER 所定义的变量，其名字都将被自动声明为全局特殊的。这意味着无论何时你在一个绑定形式—— LET 或着函数形参或者其他任何创建了新的变量绑定的构造——中使用这样一个名字，其所创建的绑定都将是一个动态绑定。这就是为什么 *命名约定* 如此重要——如果你使用了一个你认为是词法变量而它却恰好是全局特殊的变量就很不好。一方面，你调用的代码可能在你意料之外改变此变量绑定的值；另一方面，你可能会覆盖一个由绑定栈的上一级代码所建立的绑定。如果你总是按照 * 命名约定来命名全局变量，你将永远不会意外地在你想要建立一个词法绑定的地方使用一个动态绑定。

也有可能将一个变量声明为局部特殊的。如果你在一个绑定形式中声明一个名字是特殊的，那么建立在这个变量上的绑定就是动态的而不是词法的。其他代码为了引用动态绑定可以局部地声明一个特殊的名字。但是，局部特殊变量相对使用得较少，所以你不需要担心它们。¹⁷

动态绑定使全局变量更易于管理，但重要的是要注意到它们仍然允许超距行为（ action at a distance ）。绑定一个全局变量具有两种超距效果——它可以改变下游代码的行为，也开启了下游代码可以为一个由栈的上一级所建立的绑定赋予新值的可能性。你应该只在需要利用这两个特性的时候才使用动态变量。

1. 《实用Common Lisp编程》－人民邮电出版社，第1版，田春译
2. 《On Lisp中文版》 － 田春等译
3. 静态绑定和动态绑定
4. Common Lisp 变量作用域